Flash и Delphi

2006 г.

Flash и Delphi

Варибрус О.А.

Содержание

Вступление
1. Установка компоненты
2. Проигрывание Flash-ролика
- Текст основного модуля из архива Play.rar
3. Команда fsCommand и событие onFSCommand
4. Использование методов SetVariable и GetVariable для передачи данных между Flash и Delphi
- Текст модуля для демонстрации методов SetVariable и GetVariable
Заключение

Вступление

Прошло около двух лет с момента опубликования моей статьи "Flash и CBuilder". За это время я получил несколько писем с просьбой предоставить примеры на Delphi. Чтобы удовлетворить эти просьбы и по согласованию с редакцией сайта, я решил выставить данную "зеркальную" статью.

1. Установка компоненты

Чтобы иметь возможность работать с Flash-роликом, необходимо импортировать компонент ActiveX для Flash. Естественно, это возможно, если в операционной системе есть библиотека Flash.ocx или SWFlash.ocx. Эта библиотека устанавливается автоматически при установке пакета Flash или проигрывателя Flash. Последний распространяется компанией Macromedia бесплатно.

Итак, установим компоненту. Запустим Delphi. Откроем меню Component→Import ActiveX Control, появится диалоговое окно (рис. 1).

Рис 1. Диалоговое окно Import ActiveX

Поле Palette page можно не менять, если вы не хотите поместить компонент на другую страницу палитры компонентов. Найдите и выберите в списке Shockwave, откроется кнопка Install…, нажмите её, появится окно (рис. 2)

Рис. 2. Выбор пакеджа, в который будет помещаться компонент.

Рекомендуем поле File name не менять. Нажатие кнопки OK приведет к появлению окна (рис. 3)

Рис. 3. Запрос на переустановку пакеджа.

После подтверждения получаем информационное сообщение (рис. 4)

Рис. 4. Информационное сообщение

В результате всех этих манипуляций в палитре компонентов в разделе ActiveX появится новая компонента

Рис. 5. Линейка компонентов с новым компонентом в ActiveX

Подготовительный этап завершён.

2. Проигрывание Flash-ролика

Создаём на Delphi новый проект с единственной формой Form1. Из палитры компонентов ActiveX помещаем на форму компоненту ShackwaveFlash. Заносим с помощью инспектора объектов или программно в свойство ShockwaveFlash1.Movie полный путь и имя файла Flash-ролика (расширение файла swf). В примерах Flash-ролик помещён в тот же каталог, что и exe-файл, поэтому в них свойство удобно менять программно, размещая код в обработчике события создания формы:

procedure TForm1.FormCreate(Sender: TObject);
begin
  ShockwaveFlash1.Movie := ExtractFilePath(Application.ExeName) + 'ball.swf';
end;

Установите свойства ShockwaveFlash1.Loop и ShockwaveFlash1.Playing в true. Нажмем F9, чтобы провести промежуточную проверку приложения. На форме должен двигаться и деформироваться овал. Если вместо этого на форме просто белый квадрат, то, скорее всего, неправильно установлено свойство ShockwaveFlash1.Movie (файл ball.swf находится в Play.rar).

Отметим, что свойства, методы и поля класса TShockwaveFlash можно просмотреть в файле ShockwaveFlashObjects_TLB.pas (обычно он находится в "c:\Program Files\Borland\Delphi7\Imports\"). Рекомендуем сделать это. Информацию о методах можно найти на сайте компании Macromedia, в описании и в Help пакета Flash.

Теперь модифицируем наше приложение так, чтобы продемонстрировать возможности управления ходом выполнения Flash-ролика. Вид главной формы представлен на рис. 6. Кнопки Stop, Play, Back, Forward, Rewind вызывают одноименные методы ShockwaveFlash1:

Stop - останавливает выполнение ролика;
Play - инициирует выполнение ролика с текущего фрейма;
Back - переход на предыдущий фрейм;
Forward - переход на следующий фрейм;
Rewind - переход на следующий фрейм;

При нажатии кнопок Back, Forward, Rewind во время воспроизведения ролика, перед выполнением соответствующего метода производится остановка методом Stop.

Рис. 6. Вид формы

Кнопка "Перейти" совместно с CSpinEdit демонстрирует использование метода ShockwaveFlash1.GotoFrame - переход на произвольно заданный номер фрейма.

Кнопка "Загрузить новый Flash-ролик" вызывает диалоговое окно и загружает новый swf-файл. (См. предоставляемый с примером файл square.swf).

Отметим, что в программе используются:

свойство ShockwaveFlash1.TotalFrames для отображения общего количества фреймом во Flash-ролике;
метод ShockwaveFlash1.IsPlaying. Возвращаемое им значение позволяет определить, проигрывается ли в текущий момент ролик.
метод ShockwaveFlash1.CurrentFrame для отображения номера текущего фрейма при остановках.

Исходный код программы находится в архиве Play.rar.

Текст основного модуля из архива Play.rar

unit Unit1;
interface
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, Spin, OleCtrls, ShockwaveFlashObjects_TLB;
type
  TForm1 = class(TForm)
    Label1: TLabel;
    Label2: TLabel;
    Label3: TLabel;
    Label4: TLabel;
    Label5: TLabel;
    ShockwaveFlash1: TShockwaveFlash;
    Button2: TButton;
    Button3: TButton;
    Button4: TButton;
    Button5: TButton;
    Button6: TButton;
    Button7: TButton;
    SpinEdit1: TSpinEdit;
    OpenDialog1: TOpenDialog;
    Button8: TButton;
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
    procedure Button4Click(Sender: TObject);
    procedure Button5Click(Sender: TObject);
    procedure Button6Click(Sender: TObject);
    procedure Button7Click(Sender: TObject);
    procedure Button8Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
    procedure ShowCurFrame(); // показать номер текущего фрейма
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.ShowCurFrame(); // показать номер текущего фрейма
begin
  Label2.Caption :=  IntToStr(ShockwaveFlash1.CurrentFrame());  // номер текущего фрейма
  Label2.Visible := true;
end;


procedure TForm1.Button2Click(Sender: TObject);
begin
  ShockwaveFlash1.Stop();
  ShowCurFrame();
end;

procedure TForm1.Button3Click(Sender: TObject);
begin
  ShockwaveFlash1.Play();
  Label2.Visible := false;
end;

procedure TForm1.Button4Click(Sender: TObject);
begin
  if ShockwaveFlash1.IsPlaying() then
    ShockwaveFlash1.Stop();  // если проигрывается, то остановим
  ShockwaveFlash1.Back();    // на предыдущий фрейм
  ShowCurFrame();
end;

procedure TForm1.Button5Click(Sender: TObject);
begin
  if ShockwaveFlash1.IsPlaying() then
    ShockwaveFlash1.Stop();  // если проигрывается, то остановим
  ShockwaveFlash1.Forward(); // на следующий фрейм
  ShowCurFrame();
end;

procedure TForm1.Button6Click(Sender: TObject);
begin
  if ShockwaveFlash1.IsPlaying() then
    ShockwaveFlash1.Stop();  // если проигрывается, то остановим
  ShockwaveFlash1.Rewind(); // на 1-й фрейм
  ShowCurFrame();
end;

procedure TForm1.Button7Click(Sender: TObject);
begin
  ShockwaveFlash1.GotoFrame(StrToInt(SpinEdit1.Text)); // на введенный фрейм
  ShowCurFrame();
end;

procedure TForm1.Button8Click(Sender: TObject);
begin
  if OpenDialog1.Execute() then
  begin
    if (ShockwaveFlash1.IsPlaying()) then
      ShockwaveFlash1.Stop();  // если проигрывается, то остановим
    ShockwaveFlash1.Movie := OpenDialog1.FileName;
    Label4.Caption := IntToStr(ShockwaveFlash1.TotalFrames); // Общее число фреймов
    ShockwaveFlash1.Play();
    Label2.Visible := false;
  end

end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  ShockwaveFlash1.Movie := ExtractFilePath(Application.ExeName) + 'ball.swf';
  Label4.Caption := IntToStr(ShockwaveFlash1.TotalFrames); // Общее число фреймов
end;
end.

3. Команда fsCommand и событие onFSCommand

Flash-ролик может инициировать событие Delphi, а наоборот - из Delphi во Flash, к сожалению, нет. Команда скрипта fsCommand, написанная во Flash, вызывает событие onFSCommand для объекта типа TSockwaveFlash в Delphi и передаёт два параметра:

BSTR command - наименование команды;
BSTR args - параметры.

Значения этих параметров устанавливаются командой fsCommand во Flash и, в нашем случае, эти параметры могут иметь произвольные значения, которые можно использовать для обмена данными.

Приведём простой пример (см. FlashToDelphi.rar).

Запустим Macromedia Flash MX и создадим ролик следующим образом.

Поместим в единственный фрейм сцены кнопку "Oval buttons - blue" из общей библиотеки (см. рис. 7).

Рис. 7. Создание кнопки.

Теперь напишем обработчик события Release для этой кнопки, в котором разместим команду fscommand ("Click"). В данном примере передача второго параметра в команде fscommand не используется.

Это показано на рис. 8.

Рис.8. Обработчик события отпускания кнопки.

Выбор текста "Click" в качестве первого параметра в данном случае произволен.

Сохраним ролик под именем botton.fla в том же каталоге, в котором будем размещать создаваемый на Delphi проект. Нажмем Alt+Ctrl+Enter, чтобы получить botton.swf.

Создадим новый проект на Delphi. На форму поместим компонент Flash под именем ShockwaveFlash1. Сделаем программную загрузку файла botton.swf и обработку события onFSCommand, как показано ниже в тексте модуля.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, OleCtrls, ShockwaveFlashObjects_TLB;

type
  TForm1 = class(TForm)
    ShockwaveFlash1: TShockwaveFlash;
    procedure ShockwaveFlash1FSCommand(ASender: TObject; const command,
      args: WideString);
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.ShockwaveFlash1FSCommand(ASender: TObject; const command,
  args: WideString);
begin
  if command  =  'Click' then
    if Form1.Color=clWhite then
        Form1.Color := clBtnFace
    else
        Form1.Color := clWhite;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  ShockwaveFlash1.Movie := ExtractFilePath(Application.ExeName) + 'button.swf';
end;

end.

Если значение переменной x равно "Click", то форма меняет свой цвет.

Параметр arg здесь не используется, но его можно применить, чтобы передать в Delphi какую-либо информацию.

4. Использование методов SetVariable и GetVariable для передачи данных между Flash и Delphi

Демонстрации методов SetVariable и GetVariable приведены в проекте, который находится в файле DelphiToFlash.rar.

Методы объявлены в ShockwaveFlashObjects_TLB.pas следующим образом:

    procedure SetVariable(const name: WideString; const value: WideString); safecall;
    function GetVariable(const name: WideString): WideString; safecall;

Параметр name определяет полное имя переменной, значение которой устанавливается методом SetVariable или запрашивается методом GetVariable. Для метода SetVariable параметр value содержит устанавливаемое значение. Возврат значения переменной в методе GetVariable производится через имя метода.

Итак, пример использования SetVariable и GetVariable

Во Flash создаем ролик (см. рис. 9), в котором располагаем статический и динамический тексты.

Рис. 9. Flash-ролик для демонстрации SetVariable и GetVariable

В динамическом тексте меняем его имя на DelphiText и имя переменной на DelphiVarText (см. рис. 10)

Рис. 10. Свойства динамического текста

Сохраняем Flash-ролик под именем DelphiToFlash.fla (и DelphiToFlash.swf) и приступаем к созданию проекта на Delphi (см. рис. 11).

Этот проект будет передавать во Flash-ролик текст, который будет отображаться в поле динамического текста (имя этого компонента DelphiText), меняя переменную под именем DelphiVarText. Изменение будет происходить при нажатии на кнопку "Передать" (вызов метода SetVariable).

С помощью ComboBox1 будем менять цвет бордюра вокруг текста. Изменение будет происходить при любой модификации значения в ComboBox1 (опять же метод SetVariable).

Рис. 11. Форма для демонстрации методов SetVariable и GetVariable

И, наконец, демонстрация метода GetVariable с помощью кнопки "Запросить цвет бордюра из Flash-ролика" и метки с именем Label3. При нажатии на кнопку, в Label3 отобразится значение кода цвета бордюра.

Обратите внимание, что задавать цвет надо в 16-тиричном виде, а возвращается он в десятичном.

Текст модуля для демонстрации методов SetVariable и GetVariable

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, OleCtrls, ShockwaveFlashObjects_TLB, ExtCtrls, StdCtrls;

type
  TForm1 = class(TForm)
    Label1: TLabel;
    Label2: TLabel;
    Label3: TLabel;
    Button1: TButton;
    Edit1: TEdit;
    ComboBox1: TComboBox;
    Button2: TButton;
    Panel1: TPanel;
    ShockwaveFlash1: TShockwaveFlash;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure ComboBox1Change(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
begin
  ShockwaveFlash1.Movie := ExtractFilePath(Application.ExeName) + 'DelphiToFlash.swf';
  Label3.Caption :=  ShockwaveFlash1.GetVariable ('DelphiText.borderColor');
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  ShockwaveFlash1.SetVariable ('DelphiVarText', StringToOleStr(Edit1.Text));
end;

procedure TForm1.ComboBox1Change(Sender: TObject);
begin
  ShockwaveFlash1.SetVariable ('DelphiText.borderColor', StringToOleStr(ComboBox1.Text));
end;

procedure TForm1.Button2Click(Sender: TObject);
begin
  Label3.Caption := ShockwaveFlash1.GetVariable ('DelphiText.borderColor');
end;

end.

Заключение

Возможности работы с Flash-роликом через Delphi отнюдь не ограничиваются теми инструментами, которые рассматривались в статье. В частности, существует ряд методов, позволяющих работать с отдельными "мувиками", а не со всем роликом в целом. Это может дать уникальные возможности по программному управлению отдельными частями Flash-ролика в ходе его выполнения.